RECHERCHEV et DATE

[Nanisa]

Bonjour à tous et toutes

Voici ma demande :
Je vais travailler sur 3 colonnes, afin de remplir une cellule sur un autre tableau.

Sur la première ligne, je vais enregistrer la date du jour en première colonne, puis le nom d'une personne en deuxième colonne et enfin une donnée (date, calcul, texte...) en troisième colonne.
A chaque fois que je vais vouloir mettre cette troisième colonne à jour, je vais faire un copier-coller de la ligne et modifier la donnée sur cette nouvelle ligne. Cette nouvelle ligne sera datée, en première colonne, du jour de la modification.

Ainsi, mon tableau se verra incrémenté d'une ligne pour chaque mise à jour.

Sur un autre tableau, je souhaite une mise à jour automatique d'une cellule dans le format :
Je souhaite voir la donnée de la colonne 3, de la ligne dont la colonne 1 a la date la plus récente, pour le nom donné.

Exemple, si les données de "Marcel" ont été mises à jour plusieurs fois, c'est la dernière qui doit s'inscrire.

Bien entendu, il s'agit d'un exemple car j'ai bien plus de 3 colonnes, ayant de multiples données à traiter, chacune d'elles ayant sa propre colonne. Et donc plusieurs cellules destinataires dans l'autre tableau.

J'ai bien pensé faire une rechercheV intriquée avec la formule GRANDE.VALEUR (pour récupérer la date voulue) mais je m'y perds.
Et c'est là que j'appelle au secours !

GRAND.MERCI d'avance

[Sebastien]

Bonjour,

Vous pouvez oublier RECHERCHEV dans un cas pareil. On peut arriver à quelque chose en utilisant des formules matricielles.
Rappel : Pour fonctionner, une formule matricielle doit être validée par la combinaison de touche CTRL+MAJ+ENTREE.

Exemple de tableau pour l'exemple :


Dans le tableau "Source", on a les dates en colonne A, le nom en B et une donnée en C.
L'objectif est, pour un nom donné, de récupérer la donnée présente en C pour laquelle la date (en A) est la plus grande.

Je vais procéder en deux étapes :

ETAPE 1 / Récupération de la date la plus grande pour un nom donné

Dans le tableau cible, les noms sont dans la colonne F. En G2, si l'on tape la formule suivante :

Code: Tout sélectionner

=MAX(SI(F2=$B$2:$B$8;$A$2:$A$8;""))

et qu'on la valide en matricielle (CTRL+MAJ+ENTREE), la formule devient :

Code: Tout sélectionner

{=MAX(SI(F2=$B$2:$B$8;$A$2:$A$8;""))}

et retourne le résultat : 06/03/2016.

Aperçu :


On peut donc récupérer la date max pour un nom donné. Nous disposons donc d'un nom et d'une date pour effectuer notre recherche sur deux critères.

Des infos sur MAX et SI :

• Max : Les fonctions statistiques : MAX
• Si : Les fonctions logiques : SI

ETAPE 2 :
En H2 on peut, avec une combinaison de formules INDEX et EQUIV, faire une recherche des valeurs présentes en F2 et G2 dans les matrices A2:A8 et B2:B8 pour y afficher la valeur présente dans C2:C8).
A valider avec CTRL+MAJ+ENTREE pour avoir la formule en matricielle.
EQUIV va nous permettre de récupérer le numéro de ligne dans laquelle se trouve la combinaison de la date et du nom. INDEX va nous permettre d'afficher la donnée.

Code: Tout sélectionner

{=INDEX($C$2:$C$8;EQUIV(G2&F2;$A$2:$A$8&$B$2:$B$8;0))}

Des infos sur INDEX et EQUIV :

• Index : Les fonctions Recherche et Matrices : INDEX
• Equiv : Les fonctions Recherche et Matrices : EQUIV

En H2, on obtient le résultat "Données 6 mars"

Aperçu :



Si on veut une seule cellule dans le tableau cible, on peut combiner les deux étapes dans une même formule :

Code: Tout sélectionner

{=INDEX($C$2:$C$8;EQUIV(MAX(SI(F2=$B$2:$B$8;$A$2:$A$8;""))&F2;$A$2:$A$8&$B$2:$B$8;0))}

Aperçu :


@+